Add Aave v1 & v2

contracts/common/stores.sol

@@ -10,6 +10,11 @@ abstract contract Stores {
    */
   address constant internal ethAddr = 0xEeeeeEeeeEeEeeEeEeEeeEEEeeeeEeeeeeeeEEeE;
 
+  /**
+   * @dev Return Wrapped ETH address
+   */
+  address constant internal wethAddr = 0xC02aaA39b223FE8D0A0e5C4F27eAD9083C756Cc2;
+
   /**
    * @dev Return memory variable address
    */

contracts/common/utils.sol

@@ -0,0 +1,16 @@
+pragma solidity ^0.7.0;
+
+import { TokenInterface } from "./interfaces.sol";
+
+abstract contract Utils {
+    function convertEthToWeth(bool isEth, TokenInterface token, uint amount) internal {
+        if(isEth) token.deposit{value: amount}();
+    }
+
+    function convertWethToEth(bool isEth, TokenInterface token, uint amount) internal {
+       if(isEth) {
+            token.approve(address(token), amount);
+            token.withdraw(amount);
+        }
+    }
+}

contracts/connectors/aave/v1/helpers.sol

@@ -1,7 +1,7 @@
 pragma solidity ^0.7.0;
 
-import { DSMath } from "../../common/math.sol";
+import { DSMath } from "../../../common/math.sol";
-import { Basic } from "../../common/basic.sol";
+import { Basic } from "../../../common/basic.sol";
 import { AaveProviderInterface, AaveInterface } from "./interface.sol";
 
 abstract contract Helpers is DSMath, Basic {
@@ -17,6 +17,8 @@ abstract contract Helpers is DSMath, Basic {
 
     /**
      * @dev Checks if collateral is enabled for an asset
+     * @param aave Aave Interface
+     * @param token token address of the asset.(For ETH: 0xEeeeeEeeeEeEeeEeEeEeeEEEeeeeEeeeeeeeEEeE)
     */
     function getIsColl(AaveInterface aave, address token) internal view returns (bool isCol) {
         (, , , , , , , , , isCol) = aave.getUserReserveData(token, address(this));
@@ -27,7 +29,7 @@ abstract contract Helpers is DSMath, Basic {
      * @param aave Aave Interface
      * @param token token address of the collateral.(For ETH: 0xEeeeeEeeeEeEeeEeEeEeeEEEeeeeEeeeeeeeEEeE)
     */
-    function getWithdrawBalance(AaveInterface aave, address token) internal view returns (uint bal) {
+    function getCollateralBalance(AaveInterface aave, address token) internal view returns (uint bal) {
         (bal, , , , , , , , , ) = aave.getUserReserveData(token, address(this));
     }
 

contracts/connectors/aave/v1/main.sol

@@ -1,7 +1,7 @@
 pragma solidity ^0.7.0;
 
-import { TokenInterface } from "../../common/interfaces.sol";
+import { TokenInterface } from "../../../common/interfaces.sol";
-import { Stores } from "../../common/stores.sol";
+import { Stores } from "../../../common/stores.sol";
 import { Helpers } from "./helpers.sol";
 import { Events } from "./events.sol";
 import { AaveInterface, AaveCoreInterface, ATokenInterface } from "./interface.sol";
@@ -144,7 +144,7 @@ abstract contract AaveResolver is Events, Helpers {
 
         for (uint i = 0; i < _length; i++) {
             address token = tokens[i];
-            if (getWithdrawBalance(aave, token) > 0 && !getIsColl(aave, token)) {
+            if (getCollateralBalance(aave, token) > 0 && !getIsColl(aave, token)) {
                 aave.setUserUseReserveAsCollateral(token, true);
             }
         }

contracts/connectors/aave/v2/events.sol

@@ -0,0 +1,9 @@
+pragma solidity ^0.7.0;
+
+contract Events {
+    event LogDeposit(address indexed token, uint256 tokenAmt, uint256 getId, uint256 setId);
+    event LogWithdraw(address indexed token, uint256 tokenAmt, uint256 getId, uint256 setId);
+    event LogBorrow(address indexed token, uint256 tokenAmt, uint256 indexed rateMode, uint256 getId, uint256 setId);
+    event LogPayback(address indexed token, uint256 tokenAmt, uint256 indexed rateMode, uint256 getId, uint256 setId);
+    event LogEnableCollateral(address[] tokens);
+}

contracts/connectors/aave/v2/helpers.sol

@@ -0,0 +1,49 @@
+pragma solidity ^0.7.0;
+
+import { DSMath } from "../../../common/math.sol";
+import { Basic } from "../../../common/basic.sol";
+import { AaveLendingPoolProviderInterface, AaveDataProviderInterface } from "./interface.sol";
+
+abstract contract Helpers is DSMath, Basic {
+    
+    /**
+     * @dev Aave Lending Pool Provider
+    */
+    AaveLendingPoolProviderInterface constant internal aaveProvider = AaveLendingPoolProviderInterface(0xB53C1a33016B2DC2fF3653530bfF1848a515c8c5);
+
+    /**
+     * @dev Aave Protocol Data Provider
+    */
+    AaveDataProviderInterface constant internal aaveData = AaveDataProviderInterface(0x057835Ad21a177dbdd3090bB1CAE03EaCF78Fc6d);
+
+    /**
+     * @dev Aave Referral Code
+    */
+    uint16 constant internal referralCode = 3228;
+
+    /**
+     * @dev Checks if collateral is enabled for an asset
+     * @param token token address of the asset.(For ETH: 0xEeeeeEeeeEeEeeEeEeEeeEEEeeeeEeeeeeeeEEeE)
+    */
+    function getIsColl(address token) internal view returns (bool isCol) {
+        (, , , , , , , , isCol) = aaveData.getUserReserveData(token, address(this));
+    }
+
+    /**
+     * @dev Get total debt balance & fee for an asset
+     * @param token token address of the debt.(For ETH: 0xEeeeeEeeeEeEeeEeEeEeeEEEeeeeEeeeeeeeEEeE)
+     * @param rateMode Borrow rate mode (Stable = 1, Variable = 2)
+    */
+    function getPaybackBalance(address token, uint rateMode) internal view returns (uint) {
+        (, uint stableDebt, uint variableDebt, , , , , , ) = aaveData.getUserReserveData(token, address(this));
+        return rateMode == 1 ? stableDebt : variableDebt;
+    }
+
+    /**
+     * @dev Get total collateral balance for an asset
+     * @param token token address of the collateral.(For ETH: 0xEeeeeEeeeEeEeeEeEeEeeEEEeeeeEeeeeeeeEEeE)
+    */
+    function getCollateralBalance(address token) internal view returns (uint bal) {
+        (bal, , , , , , , ,) = aaveData.getUserReserveData(token, address(this));
+    }
+}

contracts/connectors/aave/v2/interface.sol

@@ -0,0 +1,46 @@
+pragma solidity ^0.7.0;
+
+interface AaveInterface {
+    function deposit(address _asset, uint256 _amount, address _onBehalfOf, uint16 _referralCode) external;
+    function withdraw(address _asset, uint256 _amount, address _to) external;
+    function borrow(
+        address _asset,
+        uint256 _amount,
+        uint256 _interestRateMode,
+        uint16 _referralCode,
+        address _onBehalfOf
+    ) external;
+    function repay(address _asset, uint256 _amount, uint256 _rateMode, address _onBehalfOf) external;
+    function setUserUseReserveAsCollateral(address _asset, bool _useAsCollateral) external;
+}
+
+interface AaveLendingPoolProviderInterface {
+    function getLendingPool() external view returns (address);
+}
+
+interface AaveDataProviderInterface {
+    function getReserveTokensAddresses(address _asset) external view returns (
+        address aTokenAddress,
+        address stableDebtTokenAddress,
+        address variableDebtTokenAddress
+    );
+    function getUserReserveData(address _asset, address _user) external view returns (
+        uint256 currentATokenBalance,
+        uint256 currentStableDebt,
+        uint256 currentVariableDebt,
+        uint256 principalStableDebt,
+        uint256 scaledVariableDebt,
+        uint256 stableBorrowRate,
+        uint256 liquidityRate,
+        uint40 stableRateLastUpdated,
+        bool usageAsCollateralEnabled
+    );
+}
+
+interface AaveAddressProviderRegistryInterface {
+    function getAddressesProvidersList() external view returns (address[] memory);
+}
+
+interface ATokenInterface {
+    function balanceOf(address _user) external view returns(uint256);
+}

contracts/connectors/aave/v2/main.sol

@@ -0,0 +1,184 @@
+pragma solidity ^0.7.0;
+
+import { TokenInterface } from "../../../common/interfaces.sol";
+import { Stores } from "../../../common/stores.sol";
+import { Utils } from "../../../common/utils.sol";
+import { Helpers } from "./helpers.sol";
+import { Events } from "./events.sol";
+import { AaveInterface } from "./interface.sol";
+
+abstract contract AaveResolver is Events, Helpers, Utils {
+    /**
+     * @dev Deposit ETH/ERC20_Token.
+     * @param token token address to deposit.(For ETH: 0xEeeeeEeeeEeEeeEeEeEeeEEEeeeeEeeeeeeeEEeE)
+     * @param amt token amount to deposit.
+     * @param getId Get token amount at this ID from `InstaMemory` Contract.
+     * @param setId Set token amount at this ID in `InstaMemory` Contract.
+    */
+    function deposit(
+        address token,
+        uint amt,
+        uint getId,
+        uint setId
+    ) external payable returns (string memory _eventName, bytes memory _eventParam) {
+        uint _amt = getUint(getId, amt);
+
+        AaveInterface aave = AaveInterface(aaveProvider.getLendingPool());
+
+        bool isEth = token == ethAddr;
+        address _token = isEth ? wethAddr : token;
+
+        TokenInterface tokenContract = TokenInterface(_token);
+
+        if (isEth) {
+            _amt = _amt == uint(-1) ? address(this).balance : _amt;
+            convertEthToWeth(isEth, tokenContract, _amt);
+        } else {
+            _amt = _amt == uint(-1) ? tokenContract.balanceOf(address(this)) : _amt;
+        }
+
+        tokenContract.approve(address(aave), _amt);
+
+        aave.deposit(_token, _amt, address(this), referralCode);
+
+        if (!getIsColl(_token)) {
+            aave.setUserUseReserveAsCollateral(_token, true);
+        }
+
+        setUint(setId, _amt);
+
+        _eventName = "LogDeposit(address,uint256,uint256,uint256)";
+        _eventParam = abi.encode(token, _amt, getId, setId);
+    }
+
+    /**
+     * @dev Withdraw ETH/ERC20_Token.
+     * @param token token address to withdraw.(For ETH: 0xEeeeeEeeeEeEeeEeEeEeeEEEeeeeEeeeeeeeEEeE)
+     * @param amt token amount to withdraw.
+     * @param getId Get token amount at this ID from `InstaMemory` Contract.
+     * @param setId Set token amount at this ID in `InstaMemory` Contract.
+    */
+    function withdraw(
+        address token,
+        uint amt,
+        uint getId,
+        uint setId
+    ) external payable returns (string memory _eventName, bytes memory _eventParam) {
+        uint _amt = getUint(getId, amt);
+
+        AaveInterface aave = AaveInterface(aaveProvider.getLendingPool());
+        bool isEth = token == ethAddr;
+        address _token = isEth ? wethAddr : token;
+
+        TokenInterface tokenContract = TokenInterface(_token);
+
+        uint initialBal = tokenContract.balanceOf(address(this));
+        aave.withdraw(_token, _amt, address(this));
+        uint finalBal = tokenContract.balanceOf(address(this));
+
+        _amt = sub(finalBal, initialBal);
+
+        convertWethToEth(isEth, tokenContract, _amt);
+        
+        setUint(setId, _amt);
+
+        _eventName = "LogWithdraw(address,uint256,uint256,uint256)";
+        _eventParam = abi.encode(token, _amt, getId, setId);
+    }
+
+    /**
+     * @dev Borrow ETH/ERC20_Token.
+     * @param token token address to borrow.(For ETH: 0xEeeeeEeeeEeEeeEeEeEeeEEEeeeeEeeeeeeeEEeE)
+     * @param amt token amount to borrow.
+     * @param rateMode type of borrow debt.(For Stable: 1, Variable: 2)
+     * @param getId Get token amount at this ID from `InstaMemory` Contract.
+     * @param setId Set token amount at this ID in `InstaMemory` Contract.
+    */
+    function borrow(
+        address token,
+        uint amt,
+        uint rateMode,
+        uint getId,
+        uint setId
+    ) external payable returns (string memory _eventName, bytes memory _eventParam) {
+        uint _amt = getUint(getId, amt);
+
+        AaveInterface aave = AaveInterface(aaveProvider.getLendingPool());
+
+        bool isEth = token == ethAddr;
+        address _token = isEth ? wethAddr : token;
+
+        aave.borrow(_token, _amt, rateMode, referralCode, address(this));
+        convertWethToEth(isEth, TokenInterface(_token), _amt);
+
+        setUint(setId, _amt);
+
+        _eventName = "LogBorrow(address,uint256,uint256,uint256,uint256)";
+        _eventParam = abi.encode(token, _amt, rateMode, getId, setId);
+    }
+
+    /**
+     * @dev Payback borrowed ETH/ERC20_Token.
+     * @param token token address to payback.(For ETH: 0xEeeeeEeeeEeEeeEeEeEeeEEEeeeeEeeeeeeeEEeE)
+     * @param amt token amount to payback.
+     * @param rateMode type of borrow debt.(For Stable: 1, Variable: 2)
+     * @param getId Get token amount at this ID from `InstaMemory` Contract.
+     * @param setId Set token amount at this ID in `InstaMemory` Contract.
+    */
+    function payback(
+        address token,
+        uint amt,
+        uint rateMode,
+        uint getId,
+        uint setId
+    ) external payable returns (string memory _eventName, bytes memory _eventParam) {
+        uint _amt = getUint(getId, amt);
+
+        AaveInterface aave = AaveInterface(aaveProvider.getLendingPool());
+
+        bool isEth = token == ethAddr;
+        address _token = isEth ? wethAddr : token;
+
+        TokenInterface tokenContract = TokenInterface(_token);
+
+        _amt = _amt == uint(-1) ? getPaybackBalance(_token, rateMode) : _amt;
+
+        if (isEth) convertEthToWeth(isEth, tokenContract, _amt);
+
+        tokenContract.approve(address(aave), _amt);
+
+        aave.repay(_token, _amt, rateMode, address(this));
+
+        setUint(setId, _amt);
+
+        _eventName = "LogPayback(address,uint256,uint256,uint256,uint256)";
+        _eventParam = abi.encode(token, _amt, rateMode, getId, setId);
+    }
+
+    /**
+     * @dev Enable collateral
+     * @param tokens Array of tokens to enable collateral
+    */
+    function enableCollateral(
+        address[] calldata tokens
+    ) external payable returns (string memory _eventName, bytes memory _eventParam) {
+        uint _length = tokens.length;
+        require(_length > 0, "0-tokens-not-allowed");
+
+        AaveInterface aave = AaveInterface(aaveProvider.getLendingPool());
+
+        for (uint i = 0; i < _length; i++) {
+            address token = tokens[i];
+            if (getCollateralBalance(token) > 0 && !getIsColl(token)) {
+                aave.setUserUseReserveAsCollateral(token, true);
+            }
+        }
+
+        _eventName = "LogEnableCollateral(address[]);";
+        _eventParam = abi.encode(tokens);
+    }
+}
+
+contract ConnectAave is AaveResolver {
+    string public name = "AaveV2-v1.1";
+}